NeHe Lesson 10: Loading And Moving Through A 3D World

[José Roca]

 
This example illustrates how to load a 3D world from a data file, and move through the 3D world.

It is an adaptation of NeHe Lesson 10: http://nehe.gamedev.net/lesson.asp?index=10

Code Select Expand


' SED_PBWIN - Use the PBWIN compiler
#COMPILE EXE
#DIM ALL
#INCLUDE "GLU.INC"
#INCLUDE "GDIPLUS.INC"
#INCLUDE "GDIPUTILS.INC"

$WindowCaption = "NeHe Lesson 10"

%GL_WINDOWWIDTH  = 640         ' Window width
%GL_WINDOWHEIGHT = 480         ' Window height
%GL_BITSPERPEL   = 16          ' Color resolution in bits per pixel
%GL_DEPTHBITS    = 16          ' Depth of the depth (z-axis) buffer

GLOBAL hDC AS LONG             ' Device context handle

TYPE VERTEX
  ' 3D Coordinates
  x AS SINGLE
  y AS SINGLE
  z AS SINGLE
  ' Texture Coordinates
  u AS SINGLE
  v AS SINGLE
END TYPE

GLOBAL TextureHandles() AS DWORD
GLOBAL numTriangles AS LONG
GLOBAL mytriangles() AS VERTEX
GLOBAL LightAmbient() AS SINGLE
GLOBAL LightDiffuse() AS SINGLE
GLOBAL LightPosition() AS SINGLE
GLOBAL zoom AS SINGLE
GLOBAL filter AS LONG
GLOBAL lookupdown AS SINGLE
GLOBAL xpos AS SINGLE
GLOBAL zpos AS SINGLE
GLOBAL heading AS SINGLE
GLOBAL walkbiasangle AS SINGLE
GLOBAL walkbias AS SINGLE
GLOBAL yrot AS SINGLE
GLOBAL blend AS LONG
GLOBAL light AS LONG

' =======================================================================================
' All the setup goes here
' =======================================================================================
SUB SetupScene (BYVAL hwnd AS DWORD, BYVAL nWidth AS LONG, BYVAL nHeight AS LONG)

   LOCAL hr AS LONG
   LOCAL strTextureData AS STRING
   LOCAL TextureWidth, TextureHeight AS LONG

   REDIM TextureHandles(2) AS DWORD

   ' Load bitmap texture from disk
   hr = GdiPlusLoadTexture("mud.bmp", TextureWidth, TextureHeight, strTextureData, %TRUE)

   ' Assign handles
   glGenTextures 3, TextureHandles(0)

   ' Create Nearest Filtered Texture
   glBindTexture %GL_TEXTURE_2D, TextureHandles(0)
   glTexParameteri %GL_TEXTURE_2D, %GL_TEXTURE_MAG_FILTER, %GL_NEAREST
   glTexParameteri %GL_TEXTURE_2D, %GL_TEXTURE_MIN_FILTER, %GL_NEAREST
   glTexImage2D %GL_TEXTURE_2D, 0, 3, TextureWidth, TextureHeight, 0, _
                %GL_RGBA, %GL_UNSIGNED_BYTE, BYVAL STRPTR(strTextureData)

   ' Create Linear Filtered Texture
   glBindTexture %GL_TEXTURE_2D, TextureHandles(1)
   glTexParameteri %GL_TEXTURE_2D, %GL_TEXTURE_MAG_FILTER, %GL_LINEAR
   glTexParameteri %GL_TEXTURE_2D, %GL_TEXTURE_MIN_FILTER, %GL_LINEAR
   glTexImage2D %GL_TEXTURE_2D, 0, 3, TextureWidth, TextureHeight, 0, _
                %GL_RGBA, %GL_UNSIGNED_BYTE, BYVAL STRPTR(strTextureData)

   ' Create MipMapped Texture
   glBindTexture %GL_TEXTURE_2D, TextureHandles(2)
   glTexParameteri %GL_TEXTURE_2D, %GL_TEXTURE_MAG_FILTER, %GL_LINEAR
   glTexParameteri %GL_TEXTURE_2D, %GL_TEXTURE_MIN_FILTER, %GL_LINEAR_MIPMAP_NEAREST
   gluBuild2DMipmaps %GL_TEXTURE_2D, 3, TextureWidth, TextureHeight, _
                     %GL_RGBA, %GL_UNSIGNED_BYTE, BYVAL STRPTR(strTextureData)

   ' Enable texture mapping
   glEnable(%GL_TEXTURE_2D)
   ' Select smooth shading
   glShadeModel %GL_SMOOTH
   ' Specify clear values for the color buffers
   glClearColor 0.0!, 0.0!, 0.0!, 0.0!
   ' Specify the clear value for the depth buffer
   glClearDepth 1.0!
   ' The type of depth test to do
   glDepthFunc %GL_LESS
   ' Enables depth testing
   glEnable %GL_DEPTH_TEST
' Really nice perspective calculations
   glHint %GL_PERSPECTIVE_CORRECTION_HINT, %GL_NICEST

   ' Set the blending function for translucency
   glBlendFunc %GL_SRC_ALPHA,%GL_ONE

   ' Setup world
   LOCAL i, c, boom, vert AS LONG
   LOCAL oneline AS STRING

   OPEN "world.txt" FOR INPUT AS #1

   DO UNTIL EOF(1)
      LINE INPUT #1, oneline
      IF LEFT$(oneline, 11) = "NUMPOLLIES " THEN
         numtriangles = VAL(MID$(oneline, 12))
         EXIT DO
      END IF
   LOOP

   REDIM mytriangles(numtriangles * 3 - 1) AS VERTEX

   FOR c = 0 TO numtriangles - 1
      FOR vert = 0 TO 2
         boom = 0
         DO
            LINE INPUT #1, oneline
            oneline = TRIM$(oneline)
            IF oneline <> "" THEN
               IF LEFT$(oneline, 2) <> "//" THEN
                  mytriangles(c * 3 + vert).x = VAL(oneline)
                  i = INSTR(oneline, " ")
                  oneline = TRIM$(MID$(oneline, i))
                  mytriangles(c * 3 + vert).y = VAL(oneline)
                  i = INSTR(oneline, " ")
                  oneline = TRIM$(MID$(oneline, i))
                  mytriangles(c * 3 + vert).z = VAL(oneline)
                  i = INSTR(oneline, " ")
                  oneline = TRIM$(MID$(oneline, i))
                  mytriangles(c * 3 + vert).u = VAL(oneline)
                  i = INSTR(oneline, " ")
                  oneline = TRIM$(MID$(oneline, i))
                  mytriangles(c * 3 + vert).v = VAL(oneline)
                  boom = 1
               END IF
            END IF
         LOOP UNTIL boom = 1
      NEXT
   NEXT
   CLOSE #1

   REDIM LightAmbient(3) AS SINGLE
   REDIM LightDiffuse(3) AS SINGLE
   REDIM LightPosition(3) AS SINGLE

   LightAmbient(0)  = 0.5! : LightAmbient(1)  = 0.5! : LightAmbient(2)  = 0.5! : LightAmbient(3)  = 1.0! ' Ambient Light
   LightDiffuse(0)  = 1.0! : LightDiffuse(1)  = 1.0! : LightDiffuse(2)  = 1.0! : LightDiffuse(3)  = 1.0! ' Diffuse Light
   LightPosition(0) = 0.0! : LightPosition(1) = 0.0! : LightPosition(2) = 2.0! : LightPosition(3) = 1.0! ' Light Position

   glLightfv %GL_LIGHT0, %GL_AMBIENT, LightAmbient(0)
   glLightfv %GL_LIGHT0, %GL_DIFFUSE, LightDiffuse(0)
   glLightfv %GL_LIGHT0, %GL_POSITION, LightPosition(0)
   glEnable %GL_LIGHT0

END SUB
' =======================================================================================

' =======================================================================================
' Resize the scene
' =======================================================================================
SUB ResizeScene (BYVAL hwnd AS DWORD, BYVAL nWidth AS LONG, BYVAL nHeight AS LONG)

   ' Prevent divide by zero making height equal one
   IF nHeight = 0 THEN nHeight = 1
   ' Reset the current viewport
   glViewport 0, 0, nWidth, nHeight
   ' Select the projection matrix
   glMatrixMode %GL_PROJECTION
   ' Reset the projection matrix
   glLoadIdentity
   ' Calculate the aspect ratio of the window
   gluPerspective 45.0!, nWidth / nHeight, 0.1!, 100.0!
   ' Select the model view matrix
   glMatrixMode %GL_MODELVIEW
   ' Reset the model view matrix
   glLoadIdentity

END SUB
' =======================================================================================

' =======================================================================================
' Draw the scene
' =======================================================================================
SUB DrawScene (BYVAL hwnd AS DWORD, BYVAL nWidth AS LONG, BYVAL nHeight AS LONG)

   LOCAL x_m, y_m, z_m, u_m, v_m AS SINGLE
   LOCAL loop_m AS LONG
   LOCAL xtrans, ztrans, ytrans AS SINGLE
   LOCAL sceneroty AS SINGLE

   ' Clear the screen buffer
   glClear %GL_COLOR_BUFFER_BIT OR %GL_DEPTH_BUFFER_BIT
   ' Reset the view
   glLoadIdentity

   xtrans = -xpos
   ztrans = -zpos
   ytrans = -walkbias - 0.25!

   sceneroty = 360.0! - yrot

   glRotatef lookupdown, 1.0!, 0,0!
   glRotatef sceneroty, 0.0!, 1.0!, 0.0!

   glTranslatef xtrans, ytrans, ztrans
   glBindTexture %GL_TEXTURE_2D, TextureHandles(filter)

   ' Process each triangle
   FOR loop_m = 0 TO numtriangles - 1 STEP 3
      glBegin %GL_TRIANGLES
      glNormal3f 0.0!, 0.0!, 1.0!
      x_m = mytriangles(loop_m + 0).x
      y_m = mytriangles(loop_m + 0).y
      z_m = mytriangles(loop_m + 0).z
      u_m = mytriangles(loop_m + 0).u
      v_m = mytriangles(loop_m + 0).v
      glTexCoord2f u_m,v_m
      glVertex3f x_m,y_m,z_m

      x_m = mytriangles(loop_m + 1).x
      y_m = mytriangles(loop_m + 1).y
      z_m = mytriangles(loop_m + 1).z
      u_m = mytriangles(loop_m + 1).u
      v_m = mytriangles(loop_m + 1).v
      glTexCoord2f u_m,v_m
      glVertex3f x_m,y_m,z_m

      x_m = mytriangles(loop_m + 2).x
      y_m = mytriangles(loop_m + 2).y
      z_m = mytriangles(loop_m + 2).z
      u_m = mytriangles(loop_m + 2).u
      v_m = mytriangles(loop_m + 2).v
      glTexCoord2f u_m,v_m
      glVertex3f x_m,y_m,z_m
      glEnd
   NEXT

   ' Dinky's light fix ;)
   glLightfv %GL_LIGHT0, %GL_POSITION, LightPosition(0)

END SUB
' =======================================================================================

' =======================================================================================
' Cleanup
' =======================================================================================
SUB Cleanup (BYVAL hwnd AS DWORD)

   ' Delete the texture
   glDeleteTextures(3, TextureHandles(0))

END SUB
' =======================================================================================

' =======================================================================================
' Processes keystrokes
' Parameters:
' * hwnd = Window hande
' * vKeyCode = Virtual key code
' * bKeyDown = %TRUE if key is pressed; %FALSE if it is released
' =======================================================================================
SUB ProcessKeystrokes (BYVAL hwnd AS DWORD, BYVAL vKeyCode AS LONG, BYVAL bKeyDown AS LONG)

   STATIC bp, fp, lp AS LONG

   SELECT CASE AS LONG vKeyCode

      CASE %VK_ESCAPE
         ' Quit if Esc key pressed
         SendMessage hwnd, %WM_CLOSE, 0, 0

      CASE %VK_B
         IF ISTRUE bKeyDown AND ISFALSE bp THEN
            bp = %TRUE
            blend = NOT blend
            IF blend THEN
               glEnable %GL_BLEND
               glDisable %GL_DEPTH_TEST
            ELSE
               glDisable %GL_BLEND
               glEnable %GL_DEPTH_TEST
            END IF
         END IF
         IF ISFALSE bKeyDown THEN bp = %FALSE

      CASE %VK_F
         IF ISTRUE bKeyDown AND ISFALSE fp THEN
            fp = %TRUE
            filter = filter + 1
            IF filter > 2 THEN filter = 0
         END IF
         IF ISFALSE bKeyDown THEN fp = %FALSE

      CASE %VK_L
         IF ISTRUE bKeyDown AND ISFALSE lp THEN
            lp = %TRUE
            light = NOT light
            IF ISFALSE light THEN
               glDisable %GL_LIGHTING
            ELSE
               glEnable %GL_LIGHTING
            END IF
         END IF
         IF ISFALSE bKeyDown THEN lp = %FALSE

      CASE %VK_PGUP
         IF ISTRUE bKeyDown THEN
            zoom = zoom - 0.02!
            lookupdown = lookupdown - 1.0!
         END IF

      CASE %VK_PGDN
         IF ISTRUE bKeyDown THEN
            zoom = zoom + 0.02!
            lookupdown = lookupdown + 1.0!
         END IF

      CASE %VK_UP
         IF ISTRUE bKeyDown THEN
            xpos = xpos - SIN(heading * 0.0174532925!) * 0.05!
            zpos = zpos - COS(heading * 0.0174532925!) * 0.05!
            IF walkbiasangle >= 359.0! THEN
               walkbiasangle = 0.0!
            ELSE
               walkbiasangle = walkbiasangle + 10
            END IF
            walkbias = SIN(walkbiasangle * 0.0174532925!) / 20.0!
         END IF

      CASE %VK_DOWN
         IF ISTRUE bKeyDown THEN
            xpos = xpos + SIN(heading * 0.0174532925!) * 0.05!
            zpos = zpos + COS(heading * 0.0174532925!) * 0.05!
            IF walkbiasangle <= 1.0! THEN
              walkbiasangle = 359.0!
            ELSE
             walkbiasangle = walkbiasangle - 10
            END IF
            walkbias = SIN(walkbiasangle * 0.0174532925!) / 20.0!
         END IF

      CASE %VK_RIGHT
         IF ISTRUE bKeyDown THEN
            heading = heading - 1.0!
            yrot = heading
         END IF

      CASE %VK_LEFT
         IF ISTRUE bKeyDown THEN
            heading = heading + 1.0!
            yrot = heading
         END IF

   END SELECT

END SUB
' =======================================================================================

' =======================================================================================
' Main
' =======================================================================================
FUNCTION WINMAIN (BYVAL hInstance AS DWORD, BYVAL hPrevInstance AS DWORD, BYVAL lpszCmdLine AS ASCIIZ PTR, BYVAL nCmdShow AS LONG) AS LONG

   LOCAL  hwnd        AS DWORD
   LOCAL  wcex        AS WNDCLASSEX
   LOCAL  szClassName AS ASCIIZ * 256
   LOCAL  szCaption   AS ASCIIZ * 256
   LOCAL  msg         AS tagMSG
   LOCAL  rc          AS RECT
   LOCAL  bDone       AS LONG
   LOCAL  nLeft       AS LONG
   LOCAL  nTop        AS LONG
   LOCAL  nWidth      AS LONG
   LOCAL  nHeight     AS LONG
   LOCAL  dwStyle     AS DWORD
   LOCAL  dwStyleEx   AS DWORD
   STATIC vKeyCode    AS LONG
   STATIC bKeyDown    AS LONG
   LOCAL  t           AS DOUBLE
   LOCAL  t0          AS DOUBLE
   LOCAL  fps         AS DOUBLE
   LOCAL  nFrames     AS LONG
   LOCAL  dm          AS DEVMODE
   LOCAL  bFullScreen AS LONG
   LOCAL  lResult     AS LONG

   ' Register the window class
   szClassName        = "PBOPENGL"
   wcex.cbSize        = SIZEOF(wcex)
   wcex.style         = %CS_HREDRAW OR %CS_VREDRAW OR %CS_OWNDC
   wcex.lpfnWndProc   = CODEPTR(WndProc)
   wcex.cbClsExtra    = 0
   wcex.cbWndExtra    = 0
   wcex.hInstance     = hInstance
   wcex.hCursor       = LoadCursor (%NULL, BYVAL %IDC_ARROW)
   wcex.hbrBackground = %NULL
   wcex.lpszMenuName  = %NULL
   wcex.lpszClassName = VARPTR(szClassName)
   wcex.hIcon         = LoadIcon (%NULL, BYVAL %IDI_APPLICATION) ' Sample, if resource icon: LoadIcon(hInst, "APPICON")
   wcex.hIconSm       = LoadIcon (%NULL, BYVAL %IDI_APPLICATION) ' Remember to set small icon too..
   RegisterClassEx wcex

' Ask the user which screen mode he prefers
lResult = MessageBox(%NULL, "Would you like to run in fullscreen mode?", _
             "Start fullScreen?", %MB_YESNOCANCEL OR %MB_ICONQUESTION)
   SELECT CASE lResult
      CASE %IDCANCEL : EXIT FUNCTION
      CASE %IDYES    : bFullScreen = %TRUE
      CASE %IDNO     : bFullScreen = %FALSE
   END SELECT

   ' Window size
   nWidth  = %GL_WINDOWWIDTH
   nHeight = %GL_WINDOWHEIGHT

   IF bFullScreen THEN
      ' Change display settings
      dm.dmSize       = SIZEOF(dm)
      dm.dmPelsWidth  = nWidth
      dm.dmPelsHeight = nHeight
      dm.dmBitsPerPel = %GL_BITSPERPEL
      dm.dmFields     = %DM_BITSPERPEL OR %DM_PELSWIDTH OR %DM_PELSHEIGHT
      IF ChangeDisplaySettings(dm, %CDS_FULLSCREEN) = 0 THEN ShowCursor %FALSE
   END IF

   ' Window caption
   szCaption = $WindowCaption

   ' Window styles
   IF ISFALSE bFullScreen THEN
      dwStyle = %WS_OVERLAPPEDWINDOW
      dwStyleEx = %WS_EX_APPWINDOW OR %WS_EX_WINDOWEDGE
   ELSE
      dwStyle = %WS_POPUP
      dwStyleEx = %WS_EX_APPWINDOW
   END IF

   ' Create the window
   hwnd = CreateWindowEx( _
            dwStyleEx, _                      ' extended styles
            szClassName, _                    ' window class name
            szCaption, _                      ' window caption
            dwStyle, _                        ' window style
            nLeft, _                          ' initial x position
            nTop, _                           ' initial y position
            nWidth, _                         ' initial x size
            nHeight, _                        ' initial y size
            %NULL, _                          ' parent window handle
            0, _                              ' window menu handle
            hInstance, _                      ' program instance handle
            BYVAL %NULL)                      ' creation parameters

   ' Retrieve the coordinates of the window's client area
   GetClientRect hwnd, rc
   ' Initialize the new OpenGl window
   SetupScene hwnd, rc.nRight - rc.nLeft, rc.nBottom - rc.nTop

   ' Show the window
   ShowWindow hwnd, nCmdShow
   UpdateWindow hwnd

   DO UNTIL bDone

      ' Windows message pump
      DO WHILE PeekMessage(msg, %NULL, 0, 0, %PM_REMOVE)
         IF msg.message = %WM_QUIT THEN
            bDone = %TRUE
         ELSE
            IF msg.message = %WM_KEYDOWN THEN
               vKeyCode = msg.wParam
               bKeyDown = %TRUE
            ELSEIF msg.message = %WM_KEYUP THEN
               vKeyCode = msg.wParam
               bKeyDown = %FALSE
            END IF
            TranslateMessage msg
            DispatchMessage msg
         END IF
      LOOP

      IF ISFALSE bFullScreen THEN
         ' Get time and mouse position
         t = INT(TIMER)
         ' Calculate and display FPS (frames per second)
         IF t > t0 OR nFrames = 0 THEN
            fps = nFrames \ (t - t0)
            wsprintf szCaption, $WindowCaption & " (%i FPS)", BYVAL fps
            SetWindowText hwnd, szCaption
            t0 = t
            nFrames = 0
         END IF
         nFrames = nFrames + 1
      END IF

      ' Draw the scene
      DrawScene hwnd, nWidth, nHeight
      ' Exchange the front and back buffers
      SwapBuffers hDC

      ' Process the keystrokes
      IF vKeyCode THEN
         ProcessKeystrokes hwnd, vKeyCode, bKeyDown
         vKeyCode = 0
      END IF

   LOOP

   ' Retore defaults
   IF bFullScreen THEN
      ChangeDisplaySettings BYVAL %NULL, 0
      ShowCursor %TRUE
   END IF

   FUNCTION = msg.wParam

END FUNCTION
' =======================================================================================

' =======================================================================================
' Main window procedure
' =======================================================================================
FUNCTION WndProc (BYVAL hwnd AS DWORD, BYVAL wMsg AS DWORD, BYVAL wParam AS DWORD, BYVAL lParam AS LONG) AS LONG

   LOCAL  pf           AS LONG
   LOCAL  pfd          AS PIXELFORMATDESCRIPTOR
   STATIC hRC          AS LONG

   SELECT CASE wMsg

      CASE %WM_SYSCOMMAND

         ' Disable the Windows screensaver
         IF (wParam AND &HFFF0) = %SC_SCREENSAVE THEN EXIT FUNCTION

         ' Close the window
         IF (wParam AND &HFFF0) = %SC_CLOSE THEN
            SendMessage hwnd, %WM_CLOSE, 0, 0
            EXIT FUNCTION
         END IF

      CASE %WM_CREATE

         ' Retrieve the device context handle
         hDC = GetDC(hwnd)

         ' Fill the PIXELFORMATDESCRIPTOR structure
         pfd.nSize           = SIZEOF(PIXELFORMATDESCRIPTOR)   ' Size of the structure
         pfd.nVersion        = 1                               ' Version number
         pfd.dwFlags         = %PFD_DRAW_TO_WINDOW _           ' Format must support window
                               OR %PFD_SUPPORT_OPENGL _        ' Format must support OpenGL
                               OR %PFD_DOUBLEBUFFER            ' Format must support double buffering
         pfd.iPixelType      = %PFD_TYPE_RGBA                  ' Request an RGBA format
         pfd.cColorBits      = %GL_BITSPERPEL                  ' Number of color bitplanes in each color buffer
         pfd.cRedBits        = 0                               ' Number of red bitplanes in each RGBA color buffer.
         pfd.cRedShift       = 0                               ' Shift count for red bitplanes in each RGBA color buffer.
         pfd.cGreenBits      = 0                               ' Number of green bitplanes in each RGBA color buffer.
         pfd.cGreenShift     = 0                               ' Shift count for green bitplanes in each RGBA color buffer.
         pfd.cBlueBits       = 0                               ' Number of blue bitplanes in each RGBA color buffer.
         pfd.cBlueShift      = 0                               ' Shift count for blue bitplanes in each RGBA color buffer.
         pfd.cAlphaBits      = 0                               ' Number of alpha bitplanes in each RGBA color buffer
         pfd.cAlphaShift     = 0                               ' Shift count for alpha bitplanes in each RGBA color buffer.
         pfd.cAccumBits      = 0                               ' Total number of bitplanes in the accumulation buffer.
         pfd.cAccumRedBits   = 0                               ' Number of red bitplanes in the accumulation buffer.
         pfd.cAccumGreenBits = 0                               ' Number of gree bitplanes in the accumulation buffer.
         pfd.cAccumBlueBits  = 0                               ' Number of blue bitplanes in the accumulation buffer.
         pfd.cAccumAlphaBits = 0                               ' Number of alpha bitplanes in the accumulation buffer.
         pfd.cDepthBits      = %GL_DEPTHBITS                   ' Depth of the depth (z-axis) buffer.
         pfd.cStencilBits    = 0                               ' Depth of the stencil buffer.
         pfd.cAuxBuffers     = 0                               ' Number of auxiliary buffers.
         pfd.iLayerType      = %PFD_MAIN_PLANE                 ' Ignored. Earlier implementations of OpenGL used this member, but it is no longer used.
         pfd.bReserved       = 0                               ' Number of overlay and underlay planes.
         pfd.dwLayerMask     = 0                               ' Ignored. Earlier implementations of OpenGL used this member, but it is no longer used.
         pfd.dwVisibleMask   = 0                               ' Transparent color or index of an underlay plane.
         pfd.dwDamageMask    = 0                               ' Ignored. Earlier implementations of OpenGL used this member, but it is no longer used.

         ' Find a matching pixel format
         pf = ChoosePixelFormat(hDC, pfd)
         IF ISFALSE pf THEN
            MessageBox hwnd, "Can't find a suitable pixel format", _
                       "Error", %MB_OK OR %MB_ICONEXCLAMATION
            SendMessage hwnd, %WM_CLOSE, 0, 0
            EXIT FUNCTION
         END IF

         ' Set the pixel format
         IF ISFALSE SetPixelFormat(hDC, pf, pfd) THEN
            MessageBox hwnd, "Can't set the pixel format", _
                       "Error", %MB_OK OR %MB_ICONEXCLAMATION
            SendMessage hwnd, %WM_CLOSE, 0, 0
            EXIT FUNCTION
         END IF

         ' Create a new OpenGL rendering context
         hRC = wglCreateContext(hDC)
         IF ISFALSE hRC THEN
            MessageBox hwnd, "Can't create an OpenGL rendering context", _
                       "Error", %MB_OK OR %MB_ICONEXCLAMATION
            SendMessage hwnd, %WM_CLOSE, 0, 0
            EXIT FUNCTION
         END IF

         ' Make it current
         IF ISFALSE wglMakeCurrent(hDC,hRC) THEN
            MessageBox hwnd, "Can't activate the OpenGL rendering context", _
                       "Error", %MB_OK OR %MB_ICONEXCLAMATION
            SendMessage hwnd, %WM_CLOSE, 0, 0
            EXIT FUNCTION
         END IF

         EXIT FUNCTION

      CASE %WM_DESTROY
         ' Clear resources
         Cleanup hwnd
         ' Release the device and rendering contexts
         wglMakeCurrent hDC, 0
         ' Make the rendering context no longer current
         wglDeleteContext hRC
         ' Release the device context
         ReleaseDC hwnd, hDC
         ' Post a WM_QUIT message
         PostQuitMessage 0
         EXIT FUNCTION

      CASE %WM_SIZE
         ResizeScene hwnd, LO(WORD, lParam), HI(WORD, lParam)
         EXIT FUNCTION

   END SELECT

   ' Call the default window procedure to process unhandled messages
   FUNCTION = DefWindowProc(hwnd, wMsg, wParam, lParam)

END FUNCTION
' =======================================================================================


[José Roca]

 
This example illustrates how to load a 3D world from a data file, and move through the 3D world.

It is an adaptation of NeHe Lesson 10: http://nehe.gamedev.net/lesson.asp?index=02

Code Select Expand


' SED_PBWIN - Use the PBWIN compiler
#COMPILE EXE
#DIM ALL
#INCLUDE ONCE "GLFW.INC"
#INCLUDE ONCE "GDIPUTILS.INC"

TYPE VERTEX
  ' 3D Coordinates
  x AS SINGLE
  y AS SINGLE
  z AS SINGLE
  ' Texture Coordinates
  u AS SINGLE
  v AS SINGLE
END TYPE

' =======================================================================================
' Main
' =======================================================================================
FUNCTION PBMAIN () AS LONG

   LOCAL hr, nWidth, nHeight, running, frames, x, y AS LONG
   LOCAL t, t0, fps AS DOUBLE
   LOCAL szTitlestr AS ASCIIZ * 200
   LOCAL strTextureData AS STRING
   LOCAL TextureWidth, TextureHeight AS LONG
   DIM   glHandles(2) AS DWORD

   LOCAL x_m, y_m, z_m, u_m, v_m AS SINGLE
   LOCAL z, xtrans, ztrans, ytrans AS SINGLE
   LOCAL lookupdown, sceneroty AS SINGLE
   LOCAL loop_m, filter, numtriangles AS LONG
   LOCAL xpos, zpos, yrot AS SINGLE
   LOCAL heading, walkbias, walkbiasangle AS SINGLE
   LOCAL blend, light, bp, fp, lp AS LONG

   ' Initialize GLFW
   glfwInit

   ' Open OpenGL window
   IF ISFALSE glfwOpenWindow(640, 480, 0, 0, 0, 0, 16, 0, %GLFW_WINDOW) THEN
      glfwTerminate
      EXIT FUNCTION
   END IF

   ' Load bitmap texture from disk
   hr = GdiPlusLoadTexture("mud.bmp", TextureWidth, TextureHeight, strTextureData, %TRUE)

   ' Assign handles
   glGenTextures 3, glHandles(0)

   ' Create Nearest Filtered Texture
   glBindTexture %GL_TEXTURE_2D, glHandles(0)
   glTexParameteri %GL_TEXTURE_2D, %GL_TEXTURE_MAG_FILTER, %GL_NEAREST
   glTexParameteri %GL_TEXTURE_2D, %GL_TEXTURE_MIN_FILTER, %GL_NEAREST
   glTexImage2D %GL_TEXTURE_2D, 0, 3, TextureWidth, TextureHeight, 0, _
                %GL_RGBA, %GL_UNSIGNED_BYTE, BYVAL STRPTR(strTextureData)

   ' Create Linear Filtered Texture
   glBindTexture %GL_TEXTURE_2D, glHandles(1)
   glTexParameteri %GL_TEXTURE_2D, %GL_TEXTURE_MAG_FILTER, %GL_LINEAR
   glTexParameteri %GL_TEXTURE_2D, %GL_TEXTURE_MIN_FILTER, %GL_LINEAR
   glTexImage2D %GL_TEXTURE_2D, 0, 3, TextureWidth, TextureHeight, 0, _
                %GL_RGBA, %GL_UNSIGNED_BYTE, BYVAL STRPTR(strTextureData)

   ' Create MipMapped Texture
   glBindTexture %GL_TEXTURE_2D, glHandles(2)
   glTexParameteri %GL_TEXTURE_2D, %GL_TEXTURE_MAG_FILTER, %GL_LINEAR
   glTexParameteri %GL_TEXTURE_2D, %GL_TEXTURE_MIN_FILTER, %GL_LINEAR_MIPMAP_NEAREST
   gluBuild2DMipmaps %GL_TEXTURE_2D, 3, TextureWidth, TextureHeight, _
                     %GL_RGBA, %GL_UNSIGNED_BYTE, BYVAL STRPTR(strTextureData)

   ' Enable texture mapping
   glEnable(%GL_TEXTURE_2D)
   ' Select smooth shading
   glShadeModel %GL_SMOOTH
   ' Specify clear values for the color buffers
   glClearColor 0.0!, 0.0!, 0.0!, 0.0!
   ' Specify the clear value for the depth buffer
   glClearDepth 1.0!
   ' The type of depth test to do
   glDepthFunc %GL_LESS
   ' Enables depth testing
   glEnable %GL_DEPTH_TEST
' Really nice perspective calculations
   glHint %GL_PERSPECTIVE_CORRECTION_HINT, %GL_NICEST

   ' Set the blending function for translucency
   glBlendFunc %GL_SRC_ALPHA,%GL_ONE

   ' Setup world
   LOCAL i, c, boom, vert AS LONG
   LOCAL oneline AS STRING

   OPEN "world.txt" FOR INPUT AS #1

   DO UNTIL EOF(1)
      LINE INPUT #1, oneline
      IF LEFT$(oneline, 11) = "NUMPOLLIES " THEN
         numtriangles = VAL(MID$(oneline, 12))
         EXIT DO
      END IF
   LOOP

   REDIM mytriangles(numtriangles * 3 - 1) AS VERTEX

   FOR c = 0 TO numtriangles - 1
      FOR vert = 0 TO 2
         boom = 0
         DO
            LINE INPUT #1, oneline
            oneline = TRIM$(oneline)
            IF oneline <> "" THEN
               IF LEFT$(oneline, 2) <> "//" THEN
                  mytriangles(c * 3 + vert).x = VAL(oneline)
                  i = INSTR(oneline, " ")
                  oneline = TRIM$(MID$(oneline, i))
                  mytriangles(c * 3 + vert).y = VAL(oneline)
                  i = INSTR(oneline, " ")
                  oneline = TRIM$(MID$(oneline, i))
                  mytriangles(c * 3 + vert).z = VAL(oneline)
                  i = INSTR(oneline, " ")
                  oneline = TRIM$(MID$(oneline, i))
                  mytriangles(c * 3 + vert).u = VAL(oneline)
                  i = INSTR(oneline, " ")
                  oneline = TRIM$(MID$(oneline, i))
                  mytriangles(c * 3 + vert).v = VAL(oneline)
                  boom = 1
               END IF
            END IF
         LOOP UNTIL boom = 1
      NEXT
   NEXT
   CLOSE #1

   REDIM LightAmbient(3) AS SINGLE
   REDIM LightDiffuse(3) AS SINGLE
   REDIM LightPosition(3) AS SINGLE

   LightAmbient(0)  = 0.5! : LightAmbient(1)  = 0.5! : LightAmbient(2)  = 0.5! : LightAmbient(3)  = 1.0! ' Ambient Light
   LightDiffuse(0)  = 1.0! : LightDiffuse(1)  = 1.0! : LightDiffuse(2)  = 1.0! : LightDiffuse(3)  = 1.0! ' Diffuse Light
   LightPosition(0) = 0.0! : LightPosition(1) = 0.0! : LightPosition(2) = 2.0! : LightPosition(3) = 1.0! ' Light Position

   glLightfv %GL_LIGHT0, %GL_AMBIENT, LightAmbient(0)
   glLightfv %GL_LIGHT0, %GL_DIFFUSE, LightDiffuse(0)
   glLightfv %GL_LIGHT0, %GL_POSITION, LightPosition(0)
   glEnable %GL_LIGHT0

   ' Enable sticky keys
   glfwEnable %GLFW_STICKY_KEYS

   ' Disable vertical sync (on cards that support it)
   glfwSwapInterval 0

   ' Main loop
   running = %TRUE
   frames = 0
   t0 = glfwGetTime

   DO WHILE running

      ' Get time and mouse position
      t = glfwGetTime
      glfwGetMousePos x, y
      ' Calculate and display FPS (frames per second)
      IF t - t0 > 1.0! OR frames = 0 THEN
         fps = frames / (t-t0)
         wsprintf szTitlestr, "NEHE Lesson 10 (%i FPS)", BYVAL fps
         glfwSetWindowTitle szTitlestr
         t0 = t
         frames = 0
      END IF
      frames = frames + 1

      '  Get window size (may be different than the requested size)
      glfwGetWindowSize nWidth, nHeight
      IF nHeight <= 0 THEN nHeight = 1

      ' Set viewport
      glViewport 0, 0, nWidth, nHeight

      ' Clear the screen and the depth buffers
      glClear %GL_COLOR_BUFFER_BIT OR %GL_DEPTH_BUFFER_BIT

      ' Select and setup the projection matrix
      glMatrixMode %GL_PROJECTION
      glLoadIdentity

      ' Calculate the aspect ratio of the window
      gluPerspective 45.0!, nWidth/nHeight, 0.1!, 100.0!

      ' Select the modelview matrix
      glMatrixMode %GL_MODELVIEW
      glLoadIdentity

      xtrans = -xpos
      ztrans = -zpos
      ytrans = -walkbias - 0.25!

      sceneroty = 360.0! - yrot

      glRotatef lookupdown, 1.0!, 0,0!
      glRotatef sceneroty, 0.0!, 1.0!, 0.0!

      glTranslatef xtrans, ytrans, ztrans
      glBindTexture %GL_TEXTURE_2D, glHandles(filter)

      ' Process each triangle
      FOR loop_m = 0 TO numtriangles - 1 STEP 3
         glBegin %GL_TRIANGLES
         glNormal3f 0.0!, 0.0!, 1.0!
         x_m = mytriangles(loop_m + 0).x
         y_m = mytriangles(loop_m + 0).y
         z_m = mytriangles(loop_m + 0).z
         u_m = mytriangles(loop_m + 0).u
         v_m = mytriangles(loop_m + 0).v
         glTexCoord2f u_m,v_m
         glVertex3f x_m,y_m,z_m

         x_m = mytriangles(loop_m + 1).x
         y_m = mytriangles(loop_m + 1).y
         z_m = mytriangles(loop_m + 1).z
         u_m = mytriangles(loop_m + 1).u
         v_m = mytriangles(loop_m + 1).v
         glTexCoord2f u_m,v_m
         glVertex3f x_m,y_m,z_m

         x_m = mytriangles(loop_m + 2).x
         y_m = mytriangles(loop_m + 2).y
         z_m = mytriangles(loop_m + 2).z
         u_m = mytriangles(loop_m + 2).u
         v_m = mytriangles(loop_m + 2).v
         glTexCoord2f u_m,v_m
         glVertex3f x_m,y_m,z_m
         glEnd
      NEXT

      ' Dinky's light fix ;)
      glLightfv %GL_LIGHT0, %GL_POSITION, LightPosition(0)

      ' Swap buffers
      glfwSwapBuffers

      ' B key
      IF glfwGetKey(66) = %GLFW_PRESS AND ISFALSE bp THEN
         bp = %TRUE
         blend = NOT blend
         IF blend THEN
            glEnable %GL_BLEND
            glDisable %GL_DEPTH_TEST
         ELSE
            glDisable %GL_BLEND
            glEnable %GL_DEPTH_TEST
         END IF
      END IF
      IF glfwGetKey(66) <> %GLFW_PRESS THEN bp = %FALSE

      ' F key
      IF glfwGetKey(70) = %GLFW_PRESS AND ISFALSE fp THEN
         fp = %TRUE
         filter = filter + 1
         IF filter > 2 THEN filter = 0
      END IF
      IF glfwGetKey(70) <> %GLFW_PRESS THEN fp = %FALSE

      ' L key
      IF glfwGetKey(76) = %GLFW_PRESS AND ISFALSE lp THEN
         lp = %TRUE
         light = NOT light
         IF ISFALSE light THEN
            glDisable %GL_LIGHTING
         ELSE
            glEnable %GL_LIGHTING
         END IF
      END IF
      IF glfwGetKey(76) <> %GLFW_PRESS THEN lp = %FALSE

      IF glfwGetKey(%GLFW_KEY_PAGEUP) = %GLFW_PRESS THEN
         z = z - 0.02!
         lookupdown = lookupdown - 1.0!
      END IF

      IF glfwGetKey(%GLFW_KEY_PAGEDOWN) = %GLFW_PRESS THEN
         z = z + 0.02!
         lookupdown = lookupdown + 1.0!
      END IF

      IF glfwGetKey(%GLFW_KEY_UP) = %GLFW_PRESS THEN
         xpos = xpos - Sin(heading * 0.0174532925!) * 0.05!
         zpos = zpos - Cos(heading * 0.0174532925!) * 0.05!
         If walkbiasangle >= 359.0! Then
            walkbiasangle = 0.0!
         Else
            walkbiasangle = walkbiasangle + 10
         End If
         walkbias = Sin(walkbiasangle * 0.0174532925!) / 20.0!
      END IF

      IF glfwGetKey(%GLFW_KEY_DOWN) = %GLFW_PRESS THEN
         xpos = xpos + Sin(heading * 0.0174532925!) * 0.05!
         zpos = zpos + Cos(heading * 0.0174532925!) * 0.05!
         If walkbiasangle <= 1.0! Then
           walkbiasangle = 359.0!
         Else
          walkbiasangle = walkbiasangle - 10
         End If
         walkbias = Sin(walkbiasangle * 0.0174532925!) / 20.0!
      END IF

      IF glfwGetKey(%GLFW_KEY_RIGHT) = %GLFW_PRESS THEN
         heading = heading - 1.0!
         yrot = heading
      END IF

      IF glfwGetKey(%GLFW_KEY_LEFT) = %GLFW_PRESS THEN
         heading = heading + 1.0!
         yrot = heading
      END IF

      ' Check if the ESC key was pressed or the window was closed
      running = NOT glfwGetKey(%GLFW_KEY_ESC) AND glfwGetWindowParam(%GLFW_OPENED)

   LOOP

   ' Delete the texture
   glDeleteTextures(3, glHandles(0))

   ' Close OpenGL window and terminate GLFW
   glfwTerminate

END FUNCTION
' =======================================================================================